| 1 | @setlocal |
| 2 | @pushd %~dp0 |
| 3 | |
| 4 | @set _C=Debug |
| 5 | @set _L=%~dp0..\..\..\build\logs |
| 6 | |
| 7 | :parse_args |
| 8 | @if /i "%1"=="release" set _C=Release |
| 9 | @if /i "%1"=="inc" set _INC=1 |
| 10 | @if /i "%1"=="clean" set _CLEAN=1 |
| 11 | @if not "%1"=="" shift & goto parse_args |
| 12 | |
| 13 | @set _B=%~dp0..\..\..\build\Util.wixext\%_C% |
| 14 | |
| 15 | :: Clean |
| 16 | |
| 17 | @if "%_INC%"=="" call :clean |
| 18 | @if NOT "%_CLEAN%"=="" goto :end |
| 19 | |
| 20 | @echo Building ext\Util %_C% using %_N% |
| 21 | |
| 22 | :: Build |
| 23 | msbuild -Restore -p:Configuration=%_C% -tl -nologo -warnaserror -bl:%_L%\ext_util_build.binlog || exit /b |
| 24 | |
| 25 | :: Test |
| 26 | dotnet test ^ |
| 27 | %_B%\net6.0\WixToolsetTest.Util.dll ^ |
| 28 | --nologo -l "trx;LogFileName=%_L%\TestResults\util.wixext.trx" || exit /b |
| 29 | |
| 30 | :: Pack |
| 31 | msbuild -t:Pack -p:Configuration=%_C% -tl -nologo -warnaserror -p:NoBuild=true wixext\WixToolset.Util.wixext.csproj || exit /b |
| 32 | |
| 33 | @goto :end |
| 34 | |
| 35 | :clean |
| 36 | @rd /s/q "..\..\build\Util.wixext" 2> nul |
| 37 | @del "..\..\build\artifacts\WixToolset.Util.wixext.*.nupkg" 2> nul |
| 38 | @del "%_L%\ext_util_build.binlog" 2> nul |
| 39 | @del "%_L%\TestResults\util.wixext.trx" 2> nul |
| 40 | @rd /s/q "%USERPROFILE%\.nuget\packages\wixtoolset.util.wixext" 2> nul |
| 41 | @exit /b |
| 42 | |
| 43 | :end |
| 44 | @popd |
| 45 | @endlocal |