| 1 | #!/usr/bin/perl |
| 2 | |
| 3 | use strict; |
| 4 | use warnings; |
| 5 | use IPC::Open2; |
| 6 | |
| 7 | # An example hook script to integrate Watchman |
| 8 | # (https://facebook.github.io/watchman/) with git to speed up detecting |
| 9 | # new and modified files. |
| 10 | # |
| 11 | # The hook is passed a version (currently 1) and a time in nanoseconds |
| 12 | # formatted as a string and outputs to stdout all files that have been |
| 13 | # modified since the given time. Paths must be relative to the root of |
| 14 | # the working tree and separated by a single NUL. |
| 15 | # |
| 16 | # To enable this hook, rename this file to "query-watchman" and set |
| 17 | # 'git config core.fsmonitor .git/hooks/query-watchman' |
| 18 | # |
| 19 | my ($version, $time) = @ARGV; |
| 20 | #print STDERR "$0 $version $time\n"; |
| 21 | |
| 22 | # Check the hook interface version |
| 23 | |
| 24 | if ($version == 1) { |
| 25 | # convert nanoseconds to seconds |
| 26 | # subtract one second to make sure watchman will return all changes |
| 27 | $time = int ($time / 1000000000) - 1; |
| 28 | } else { |
| 29 | exit 1; |
| 30 | } |
| 31 | |
| 32 | my $git_work_tree; |
| 33 | if ($^O =~ 'msys' || $^O =~ 'cygwin') { |
| 34 | $git_work_tree = Win32::GetCwd(); |
| 35 | $git_work_tree =~ tr/\\/\//; |
| 36 | } else { |
| 37 | require Cwd; |
| 38 | $git_work_tree = Cwd::cwd(); |
| 39 | } |
| 40 | |
| 41 | launch_watchman(); |
| 42 | |
| 43 | sub launch_watchman { |
| 44 | |
| 45 | my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j') |
| 46 | or die "open2() failed: $!\n" . |
| 47 | "Falling back to scanning...\n"; |
| 48 | |
| 49 | # In the query expression below we're asking for names of files that |
| 50 | # changed since $time but were not transient (ie created after |
| 51 | # $time but no longer exist). |
| 52 | # |
| 53 | # To accomplish this, we're using the "since" generator to use the |
| 54 | # recency index to select candidate nodes and "fields" to limit the |
| 55 | # output to file names only. |
| 56 | |
| 57 | my $query = <<" END"; |
| 58 | ["query", "$git_work_tree", { |
| 59 | "since": $time, |
| 60 | "fields": ["name"] |
| 61 | }] |
| 62 | END |
| 63 | |
| 64 | open (my $fh, ">", ".git/watchman-query.json"); |
| 65 | print $fh $query; |
| 66 | close $fh; |
| 67 | |
| 68 | print CHLD_IN $query; |
| 69 | close CHLD_IN; |
| 70 | my $response = do {local $/; <CHLD_OUT>}; |
| 71 | |
| 72 | open ($fh, ">", ".git/watchman-response.json"); |
| 73 | print $fh $response; |
| 74 | close $fh; |
| 75 | |
| 76 | die "Watchman: command returned no output.\n" . |
| 77 | "Falling back to scanning...\n" if $response eq ""; |
| 78 | die "Watchman: command returned invalid output: $response\n" . |
| 79 | "Falling back to scanning...\n" unless $response =~ /^\{/; |
| 80 | |
| 81 | my $json_pkg; |
| 82 | eval { |
| 83 | require JSON::XS; |
| 84 | $json_pkg = "JSON::XS"; |
| 85 | 1; |
| 86 | } or do { |
| 87 | require JSON::PP; |
| 88 | $json_pkg = "JSON::PP"; |
| 89 | }; |
| 90 | |
| 91 | my $o = $json_pkg->new->utf8->decode($response); |
| 92 | |
| 93 | if ($o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) { |
| 94 | print STDERR "Adding '$git_work_tree' to watchman's watch list.\n"; |
| 95 | qx/watchman watch "$git_work_tree"/; |
| 96 | die "Failed to make watchman watch '$git_work_tree'.\n" . |
| 97 | "Falling back to scanning...\n" if $? != 0; |
| 98 | |
| 99 | # Watchman will always return all files on the first query so |
| 100 | # return the fast "everything is dirty" flag to git and do the |
| 101 | # Watchman query just to get it over with now so we won't pay |
| 102 | # the cost in git to look up each individual file. |
| 103 | |
| 104 | open ($fh, ">", ".git/watchman-output.out"); |
| 105 | print "/\0"; |
| 106 | close $fh; |
| 107 | |
| 108 | print "/\0"; |
| 109 | exit 0; |
| 110 | } |
| 111 | |
| 112 | die "Watchman: $o->{error}.\n" . |
| 113 | "Falling back to scanning...\n" if $o->{error}; |
| 114 | |
| 115 | open ($fh, ">", ".git/watchman-output.out"); |
| 116 | binmode $fh, ":utf8"; |
| 117 | print $fh @{$o->{files}}; |
| 118 | close $fh; |
| 119 | |
| 120 | binmode STDOUT, ":utf8"; |
| 121 | local $, = "\0"; |
| 122 | print @{$o->{files}}; |
| 123 | } |