| 1 | /* |
| 2 | * Test early exception recognition using STOSM. |
| 3 | * |
| 4 | * SPDX-License-Identifier: GPL-2.0-or-later |
| 5 | */ |
| 6 | .org 0x8d |
| 7 | ilc: |
| 8 | .org 0x8e |
| 9 | program_interruption_code: |
| 10 | .org 0x150 |
| 11 | program_old_psw: |
| 12 | .org 0x1D0 /* program new PSW */ |
| 13 | .quad 0,pgm |
| 14 | .org 0x200 /* lowcore padding */ |
| 15 | |
| 16 | .globl _start |
| 17 | _start: |
| 18 | stosm ssm_op,0x10 /* bit 3 set */ |
| 19 | expected_pswa: |
| 20 | j failure |
| 21 | |
| 22 | pgm: |
| 23 | chhsi program_interruption_code,0x6 /* specification exception? */ |
| 24 | jne failure |
| 25 | cli ilc,4 /* ilc for STOSM? */ |
| 26 | jne failure |
| 27 | clc program_old_psw(16),expected_old_psw /* correct old PSW? */ |
| 28 | jne failure |
| 29 | lpswe success_psw |
| 30 | failure: |
| 31 | lpswe failure_psw |
| 32 | |
| 33 | ssm_op: |
| 34 | .byte 0 |
| 35 | .align 8 |
| 36 | expected_old_psw: |
| 37 | .quad 0x1000000180000000,expected_pswa /* bit 3 set */ |
| 38 | success_psw: |
| 39 | .quad 0x2000000000000,0xfff /* see is_special_wait_psw() */ |
| 40 | failure_psw: |
| 41 | .quad 0x2000000000000,0 /* disabled wait */ |