| 1 | #compdef git gitk |
| 2 | |
| 3 | # zsh completion wrapper for git |
| 4 | # |
| 5 | # Copyright (c) 2012-2020 Felipe Contreras <felipe.contreras@gmail.com> |
| 6 | # |
| 7 | # The recommended way to install this script is to make a copy of it as a |
| 8 | # file named '_git' inside any directory in your fpath. |
| 9 | # |
| 10 | # For example, create a directory '~/.zsh/', copy this file to '~/.zsh/_git', |
| 11 | # and then add the following to your ~/.zshrc file: |
| 12 | # |
| 13 | # fpath=(~/.zsh $fpath) |
| 14 | # |
| 15 | # You need git's bash completion script installed. By default bash-completion's |
| 16 | # location will be used (e.g. pkg-config --variable=completionsdir bash-completion). |
| 17 | # |
| 18 | # If your bash completion script is somewhere else, you can specify the |
| 19 | # location in your ~/.zshrc: |
| 20 | # |
| 21 | # zstyle ':completion:*:*:git:*' script ~/.git-completion.bash |
| 22 | # |
| 23 | |
| 24 | zstyle -T ':completion:*:*:git:*' tag-order && \ |
| 25 | zstyle ':completion:*:*:git:*' tag-order 'common-commands' |
| 26 | |
| 27 | zstyle -s ":completion:*:*:git:*" script script |
| 28 | if [ -z "$script" ]; then |
| 29 | local -a locations |
| 30 | local e bash_completion |
| 31 | |
| 32 | bash_completion=$(pkg-config --variable=completionsdir bash-completion 2>/dev/null) || |
| 33 | bash_completion='/usr/share/bash-completion/completions/' |
| 34 | |
| 35 | locations=( |
| 36 | "$(dirname ${funcsourcetrace[1]%:*})"/git-completion.bash |
| 37 | "$HOME/.local/share/bash-completion/completions/git" |
| 38 | "$bash_completion/git" |
| 39 | '/etc/bash_completion.d/git' # old debian |
| 40 | ) |
| 41 | for e in $locations; do |
| 42 | test -f $e && script="$e" && break |
| 43 | done |
| 44 | fi |
| 45 | |
| 46 | local old_complete="$functions[complete]" |
| 47 | functions[complete]=: |
| 48 | GIT_SOURCING_ZSH_COMPLETION=y . "$script" |
| 49 | functions[complete]="$old_complete" |
| 50 | |
| 51 | __gitcomp () |
| 52 | { |
| 53 | emulate -L zsh |
| 54 | |
| 55 | local cur_="${3-$cur}" |
| 56 | |
| 57 | case "$cur_" in |
| 58 | --*=) |
| 59 | ;; |
| 60 | --no-*) |
| 61 | local c IFS=$' \t\n' |
| 62 | local -a array |
| 63 | for c in ${=1}; do |
| 64 | if [[ $c == "--" ]]; then |
| 65 | continue |
| 66 | fi |
| 67 | c="$c${4-}" |
| 68 | case $c in |
| 69 | --*=|*.) ;; |
| 70 | *) c="$c " ;; |
| 71 | esac |
| 72 | array+=("$c") |
| 73 | done |
| 74 | compset -P '*[=:]' |
| 75 | compadd -Q -S '' -p "${2-}" -a -- array && _ret=0 |
| 76 | ;; |
| 77 | *) |
| 78 | local c IFS=$' \t\n' |
| 79 | local -a array |
| 80 | for c in ${=1}; do |
| 81 | if [[ $c == "--" ]]; then |
| 82 | c="--no-...${4-}" |
| 83 | array+=("$c ") |
| 84 | break |
| 85 | fi |
| 86 | c="$c${4-}" |
| 87 | case $c in |
| 88 | --*=|*.) ;; |
| 89 | *) c="$c " ;; |
| 90 | esac |
| 91 | array+=("$c") |
| 92 | done |
| 93 | compset -P '*[=:]' |
| 94 | compadd -Q -S '' -p "${2-}" -a -- array && _ret=0 |
| 95 | ;; |
| 96 | esac |
| 97 | } |
| 98 | |
| 99 | __gitcomp_direct () |
| 100 | { |
| 101 | emulate -L zsh |
| 102 | |
| 103 | compset -P '*[=:]' |
| 104 | compadd -Q -S '' -- ${(f)1} && _ret=0 |
| 105 | } |
| 106 | |
| 107 | __gitcomp_nl () |
| 108 | { |
| 109 | emulate -L zsh |
| 110 | |
| 111 | compset -P '*[=:]' |
| 112 | compadd -Q -S "${4- }" -p "${2-}" -- ${(f)1} && _ret=0 |
| 113 | } |
| 114 | |
| 115 | __gitcomp_file () |
| 116 | { |
| 117 | emulate -L zsh |
| 118 | |
| 119 | compset -P '*[=:]' |
| 120 | compadd -f -p "${2-}" -- ${(f)1} && _ret=0 |
| 121 | } |
| 122 | |
| 123 | __gitcomp_direct_append () |
| 124 | { |
| 125 | __gitcomp_direct "$@" |
| 126 | } |
| 127 | |
| 128 | __gitcomp_nl_append () |
| 129 | { |
| 130 | __gitcomp_nl "$@" |
| 131 | } |
| 132 | |
| 133 | __gitcomp_file_direct () |
| 134 | { |
| 135 | __gitcomp_file "$1" "" |
| 136 | } |
| 137 | |
| 138 | _git_zsh () |
| 139 | { |
| 140 | __gitcomp "v1.1" |
| 141 | } |
| 142 | |
| 143 | __git_complete_command () |
| 144 | { |
| 145 | emulate -L zsh |
| 146 | |
| 147 | local command="$1" |
| 148 | local completion_func="_git_${command//-/_}" |
| 149 | if (( $+functions[$completion_func] )); then |
| 150 | emulate ksh -c $completion_func |
| 151 | return 0 |
| 152 | else |
| 153 | return 1 |
| 154 | fi |
| 155 | } |
| 156 | |
| 157 | __git_zsh_bash_func () |
| 158 | { |
| 159 | emulate -L ksh |
| 160 | |
| 161 | local command=$1 |
| 162 | |
| 163 | __git_complete_command "$command" && return |
| 164 | |
| 165 | local expansion=$(__git_aliased_command "$command") |
| 166 | if [ -n "$expansion" ]; then |
| 167 | words[1]=$expansion |
| 168 | __git_complete_command "$expansion" |
| 169 | fi |
| 170 | } |
| 171 | |
| 172 | __git_zsh_cmd_common () |
| 173 | { |
| 174 | local -a list |
| 175 | list=( |
| 176 | add:'add file contents to the index' |
| 177 | bisect:'find by binary search the change that introduced a bug' |
| 178 | branch:'list, create, or delete branches' |
| 179 | checkout:'checkout a branch or paths to the working tree' |
| 180 | clone:'clone a repository into a new directory' |
| 181 | commit:'record changes to the repository' |
| 182 | diff:'show changes between commits, commit and working tree, etc' |
| 183 | fetch:'download objects and refs from another repository' |
| 184 | grep:'print lines matching a pattern' |
| 185 | init:'create an empty Git repository or reinitialize an existing one' |
| 186 | log:'show commit logs' |
| 187 | merge:'join two or more development histories together' |
| 188 | mv:'move or rename a file, a directory, or a symlink' |
| 189 | pull:'fetch from and merge with another repository or a local branch' |
| 190 | push:'update remote refs along with associated objects' |
| 191 | rebase:'forward-port local commits to the updated upstream head' |
| 192 | reset:'reset current HEAD to the specified state' |
| 193 | restore:'restore working tree files' |
| 194 | rm:'remove files from the working tree and from the index' |
| 195 | show:'show various types of objects' |
| 196 | status:'show the working tree status' |
| 197 | switch:'switch branches' |
| 198 | tag:'create, list, delete or verify a tag object signed with GPG') |
| 199 | _describe -t common-commands 'common commands' list && _ret=0 |
| 200 | } |
| 201 | |
| 202 | __git_zsh_cmd_alias () |
| 203 | { |
| 204 | local -a list |
| 205 | list=(${(0)"$(git help --aliases-for-completion)"}) |
| 206 | list=(${(f)"$(printf "%s:alias for '%s'\n" ${(f@)list})"}) |
| 207 | _describe -t alias-commands 'aliases' list && _ret=0 |
| 208 | } |
| 209 | |
| 210 | __git_zsh_cmd_all () |
| 211 | { |
| 212 | local -a list |
| 213 | emulate ksh -c __git_compute_all_commands |
| 214 | list=( ${=__git_all_commands} ) |
| 215 | _describe -t all-commands 'all commands' list && _ret=0 |
| 216 | } |
| 217 | |
| 218 | __git_zsh_main () |
| 219 | { |
| 220 | local curcontext="$curcontext" state state_descr line |
| 221 | typeset -A opt_args |
| 222 | local -a orig_words |
| 223 | |
| 224 | orig_words=( ${words[@]} ) |
| 225 | |
| 226 | _arguments -C \ |
| 227 | '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \ |
| 228 | '(-p --paginate)--no-pager[do not pipe git output into a pager]' \ |
| 229 | '--git-dir=-[set the path to the repository]: :_directories' \ |
| 230 | '--bare[treat the repository as a bare repository]' \ |
| 231 | '(- :)--version[prints the git suite version]' \ |
| 232 | '--exec-path=-[path to where your core git programs are installed]:: :_directories' \ |
| 233 | '--html-path[print the path where git''s HTML documentation is installed]' \ |
| 234 | '--info-path[print the path where the Info files are installed]' \ |
| 235 | '--man-path[print the manpath (see `man(1)`) for the man pages]' \ |
| 236 | '--work-tree=-[set the path to the working tree]: :_directories' \ |
| 237 | '--namespace=-[set the git namespace]' \ |
| 238 | '--no-replace-objects[do not use replacement refs to replace git objects]' \ |
| 239 | '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \ |
| 240 | '(-): :->command' \ |
| 241 | '(-)*:: :->arg' && return |
| 242 | |
| 243 | case $state in |
| 244 | (command) |
| 245 | _tags common-commands alias-commands all-commands |
| 246 | while _tags; do |
| 247 | _requested common-commands && __git_zsh_cmd_common |
| 248 | _requested alias-commands && __git_zsh_cmd_alias |
| 249 | _requested all-commands && __git_zsh_cmd_all |
| 250 | let _ret || break |
| 251 | done |
| 252 | ;; |
| 253 | (arg) |
| 254 | local command="${words[1]}" __git_dir __git_cmd_idx=1 |
| 255 | |
| 256 | if (( $+opt_args[--bare] )); then |
| 257 | __git_dir='.' |
| 258 | else |
| 259 | __git_dir=${opt_args[--git-dir]} |
| 260 | fi |
| 261 | |
| 262 | (( $+opt_args[--help] )) && command='help' |
| 263 | |
| 264 | words=( ${orig_words[@]} ) |
| 265 | |
| 266 | __git_zsh_bash_func $command |
| 267 | ;; |
| 268 | esac |
| 269 | } |
| 270 | |
| 271 | _git () |
| 272 | { |
| 273 | local _ret=1 |
| 274 | local cur cword prev |
| 275 | local __git_repo_path |
| 276 | |
| 277 | cur=${words[CURRENT]} |
| 278 | prev=${words[CURRENT-1]} |
| 279 | let cword=CURRENT-1 |
| 280 | |
| 281 | if (( $+functions[__${service}_zsh_main] )); then |
| 282 | __${service}_zsh_main |
| 283 | elif (( $+functions[__${service}_main] )); then |
| 284 | emulate ksh -c __${service}_main |
| 285 | elif (( $+functions[_${service}] )); then |
| 286 | emulate ksh -c _${service} |
| 287 | elif (( $+functions[_${service//-/_}] )); then |
| 288 | emulate ksh -c _${service//-/_} |
| 289 | fi |
| 290 | |
| 291 | let _ret && _default && _ret=0 |
| 292 | return _ret |
| 293 | } |
| 294 | |
| 295 | _git |