| 1 | git_subtree = custom_target( |
| 2 | input: 'git-subtree.sh', |
| 3 | output: 'git-subtree', |
| 4 | command: [ |
| 5 | shell, |
| 6 | meson.project_source_root() / 'tools/generate-script.sh', |
| 7 | '@INPUT@', |
| 8 | '@OUTPUT@', |
| 9 | meson.project_build_root() / 'GIT-BUILD-OPTIONS', |
| 10 | ], |
| 11 | install: true, |
| 12 | install_dir: get_option('libexecdir') / 'git-core', |
| 13 | ) |
| 14 | |
| 15 | if get_option('tests') |
| 16 | subtree_test_environment = test_environment |
| 17 | subtree_test_environment.prepend('PATH', meson.current_build_dir()) |
| 18 | |
| 19 | test('t7900-subtree', shell, |
| 20 | args: [ 't7900-subtree.sh' ], |
| 21 | env: subtree_test_environment, |
| 22 | workdir: meson.current_source_dir() / 't', |
| 23 | depends: test_dependencies + bin_wrappers + [ git_subtree ], |
| 24 | kwargs: test_kwargs, |
| 25 | ) |
| 26 | endif |
| 27 | |
| 28 | if get_option('docs').contains('man') |
| 29 | subtree_xml = custom_target( |
| 30 | command: asciidoc_common_options + [ |
| 31 | '--backend=' + asciidoc_docbook, |
| 32 | '--doctype=manpage', |
| 33 | '--out-file=@OUTPUT@', |
| 34 | '@INPUT@', |
| 35 | ], |
| 36 | depends: documentation_deps, |
| 37 | input: 'git-subtree.adoc', |
| 38 | output: 'git-subtree.xml', |
| 39 | ) |
| 40 | |
| 41 | doc_targets += custom_target( |
| 42 | command: [ |
| 43 | xmlto, |
| 44 | '-m', '@INPUT@', |
| 45 | 'man', |
| 46 | subtree_xml, |
| 47 | '-o', |
| 48 | meson.current_build_dir(), |
| 49 | ] + xmlto_extra, |
| 50 | input: [ |
| 51 | '../../Documentation/manpage-normal.xsl', |
| 52 | ], |
| 53 | output: 'git-subtree.1', |
| 54 | install: true, |
| 55 | install_dir: get_option('mandir') / 'man1', |
| 56 | ) |
| 57 | endif |
| 58 | |
| 59 | if get_option('docs').contains('html') |
| 60 | doc_targets += custom_target( |
| 61 | command: asciidoc_common_options + [ |
| 62 | '--backend=' + asciidoc_html, |
| 63 | '--doctype=manpage', |
| 64 | '--out-file=@OUTPUT@', |
| 65 | '@INPUT@', |
| 66 | ], |
| 67 | depends: documentation_deps, |
| 68 | input: 'git-subtree.adoc', |
| 69 | output: 'git-subtree.html', |
| 70 | install: true, |
| 71 | install_dir: htmldir, |
| 72 | ) |
| 73 | endif |